build.gradle

buildscript {
    repositories {
        mavenLocal()
        mavenCentral()
    }

    dependencies {
        classpath 'commons-codec:commons-codec:1.10'
    }
}

plugins {
    id 'edu.wpi.first.wpilib.versioning.WPILibVersioningPlugin' version '1.6'
    id 'de.undercouch.download' version '3.2.0'
}

import org.apache.commons.codec.digest.DigestUtils

def jreRelease = 'v2018.1'
def jreFile = 'zulu-jre_1.8.0-131_cortexa9-vfpv3.ipk'

task downloadJRE() {
    group = 'Build'
    description = 'Downloads JRE ipk.'

    def destFile = new File('edu.wpi.first.wpilib.plugins.java/src/main/resources/java-zip/ant/', jreFile)
    def golden = 'a7e339f21c44e01017538e96fdf07963d5a22b25fd3b61456306699a24993500'

    String checksum
    if (destFile.exists()) {
        destFile.withInputStream { ins -> checksum = DigestUtils.sha256Hex(ins) }
    }
    if (checksum != golden) {
        download {
            src "/~https://github.com/wpilibsuite/zulu-jre-ipk/releases/download/${jreRelease}/${jreFile}"
            dest destFile
            overwrite true
        }
        destFile.withInputStream { ins -> checksum = DigestUtils.sha256Hex(ins) }
        if (checksum != golden) {
            throw new GradleException("download checksum did not match")
        }
    }
}

def niPropertiesSource = file('ni_image.properties')
def niPropertiesSpec = copySpec {
    from niPropertiesSource
}

task generateNiImageProperties() {
    group = 'Build'
    description = 'Generates ni_image.properties.'
    def cppPropFile = file('edu.wpi.first.wpilib.plugins.cpp/src/main/resources/cpp-zip/ant/')
    def javaPropFile = file('edu.wpi.first.wpilib.plugins.java/src/main/resources/java-zip/ant/')

    inputs.file niPropertiesSource
    outputs.files cppPropFile, javaPropFile

    doLast {
        [cppPropFile, javaPropFile].each { dest ->
            copy {
                with niPropertiesSpec
                into dest
            }
        }
    }
}

apply from: 'maven_commands.gradle'

executeMaven.mustRunAfter generateNiImageProperties, downloadJRE

def generatedVersionFile = file('generated_version')

task updateDependencies() {
    group = 'Build'
    description = 'Updates the versions of all edu.wpi.first.*:* dependencies to the latest version available.'
    dependsOn updateWPILibVersionCommand, updateDependencyVersionsCommand, executeMaven

    doLast {
        if (!generatedVersionFile.exists()) {
            generatedVersionFile.createNewFile()
        }
    }
}

task build() {
    group = 'Build'
    description = 'Assembles this project.'
    dependsOn generateNiImageProperties, downloadJRE, addPackageCommand, executeMaven

    // If this is an official build, or if we have never updates the dependencies (ie, this is a fresh clone), or if
    // the user has specified always update dependencies, we update the version of the plugin and of our dependencies
    if (WPILibVersion.releaseType.toString().equalsIgnoreCase('official') || generatedFileCheck(generatedVersionFile)) {
        dependsOn updateDependencies
    }
}

task assemble() {
    group = 'Build'
    description = 'Assembles the outputs of this project.'
    dependsOn build
}

task check() {
    group = 'Verification'
    description = 'Runs all checks.'
    dependsOn assemble
}

task mvnClean() {
    group = 'Build'
    description = 'Runs a \'mvn clean\'.'
    dependsOn executeMaven, addCleanCommand
}

task clean(type: Delete) {
    group = 'Build'
    description = 'Deletes the built artifacts.'
    dependsOn mvnClean
}

task wrapper(type: Wrapper) {
    gradleVersion = '4.1'
}

// If the generatedVersionFile doesn't exist, or if it's content is 'always generate' ignoring case, then return true.
def generatedFileCheck(generatedVersionFile) {
    if (generatedVersionFile.exists()) {
        def content = generatedVersionFile.text
        return content.equalsIgnoreCase('always generate')
    } else {
        return true
    }
}