PMASIAUJ - Chapter 5, Exercise 1c - This works, but is there a better way?

[mindcrime]

Hi all, I'm still working my way through the PMASIAUJ book and have just finished implementing section C of Exercise 1 in Chapter 5, where we are asked to

c. Increase the environment model to a 10x10 grid using the same design pattern as the Domestic Robot System.

for the vacuum cleaner example. I probably went a bit further than the exercise intended, but I'm trying to make sure I understand all this. What I did works, but curious if there is a more idiomatic or preferred way to accomplish this.

Briefly, here's what I did. I made my grid world 10x10 using the same setup as the Domestic Robot example. Then I randomly initialized some dirty squares and set my vacuum agent to the task of cleaning the room. I did not try to do anything fancy as far as navigation or pathfinding, since that seemed beyond the scope of what I'm trying to do. So I just have the vacuum jump to the upper left square (it starts in a random location) and then navigate from left to right until it hits the rightmost square, then it jumps "down and full left" then starts going right again, lather rinse repeat until the numdirty(X) percept is 0. In my Environment / Model I insert percepts for how many squares to the right remain available and how many rowsn down remain available.

My AgentSpeak code looks like this:

@c1[atomic] +!cleanroom : not visited_upper_left <- .print( "Starting to clean room!" ); goto_upper_left; !cleanroom.
@c2[atomic] +!cleanroom : numdirty(X) & X > 0 & (rows_down_available & squares_right_available) <- .print( "going right"); suck; right; !cleanroom.
@c3[atomic] +!cleanroom : numdirty(X) & X > 0 & (rows_down_available & not squares_right_available) <- .print( "going down and left"); down; full_left; !cleanroom.
@c4[atomic] +!cleanroom : numdirty(X) & X > 0 & (not rows_down_available & squares_right_available) <- .print( "going right"); suck; right; !cleanroom.
@c5[atomic] +!cleanroom : numdirty(X) & X == 0  <- .succeed_goal(cleanroom).

+!exit : true <- .stopMAS.

+numdirty(X) : (X == 0) <- .print( "All squares are clean!" ); !exit.
+numdirty(X) : (X >= 1) <- !cleanroom.

Initially the 'visited_upper_left' percept is missing so the first action executed is the goto_upper_left. From there the vacuum starts navigating right, suck()'ing any dirty squares, and so on until it's finished. It quits by calling succeed_goal(cleanroom) when no more dirty squares remain. Calling stopMAS is just a convenience so the program quits so it's easy to just up-arrow in my terminal and hit ENTER to run it again. :-)

This works, but I'd love to hear if there are markedly better ways to go about this, or really any other feedback the experts might have.

Full source code available here.

[jomifred]

Hi Phillip, great you are progressing! (and animating the discussion about Jason)

Initial reaction:

1. good you opted for a goal oriented approach instead of an event oriented!

2. equality tests like X == 0 are usually unnecessary in logic programming, unification may be used in place. For instance +numdirty(X) : (X == 0)... -> +numdirty(0) .... It occurs in @C5 too.

3. it seems several intentions for goal cleanroom will be running, triggered by the last plan. Maybe it is better to ensure just one intention. Could cleanroom be an initial goal?

4. not clear why you have to add the atomic annotations for the plans... (maybe it is related to 3.)

5. plans c2 and c4 seems the same... could it be that only c2 exists removing the part rows_down_available & ?

6. why .succeed_goal(cleanroom) in the c5? Maybe just +!cleanroom : numdirty(0). is enough.... Indeed it could be the first plan. Take a look at goal patterns here.

[mindcrime]

Thanks Jomi. I think you hit on multiple points that all relate to the same issue:

(3) - Yes, this approach seems to wind up with multiple intentions running.

(4) - And given that, without the atomic annotation, the state gets all jumbled up since things happen "out of order"

(6) - Similar thing... once all the squares are clean, this "wants" to execute multiple times as the stack unwinds. I temporarily just put a .print("NOP"). in there and without the explicit succeed_goal I get a whole pile of "NOP" lines in my output. Not strictly harmful in this trivial example, but undesirable.

Maybe it is better to ensure just one intention. Could cleanroom be an initial goal?

It's not clear to me exactly how to structure this so that I have only one intention running. I'll read over the goal patterns doc you linked, and spend some more time thinking about it. But if you have any other advice on this point you're willing to share in the meantime, I'd love to hear it.

[mindcrime]

OK, I think I (kinda) get it now. I did this to my AgentSpeak code, while leaving the Environment and Model code exactly the same:

// Per Jomi's suggestion, start with an initial goal of !cleanroom
!cleanroom.

@c1 +!cleanroom : not visited_upper_left <- .print( "Starting to clean room!" ); goto_upper_left; !cleanroom.
@c2 +!cleanroom : numdirty(X) & X > 0 & (rows_down_available & squares_right_available) <- .print( "going right"); suck; right; !cleanroom.
// @c4 +!cleanroom : numdirty(X) & X > 0 & (not rows_down_available & squares_right_available) <- .print( "going right"); suck; right; !cleanroom.
@c3 +!cleanroom : numdirty(X) & X > 0 & (rows_down_available & not squares_right_available) <- .print( "going down and left"); down; full_left; !cleanroom.
@c4 +!cleanroom : numdirty(X) & X == 0  <- .print( "Done" ).

Aside from starting with a !cleanroom goal, I also removed the 'atomic' annotation from all plans and took out the code that was adding the achievement goal !cleanroom in response to the +numdirty believe addition. And I commented out the old plan @C4 which was indeed redundant with @c2.

I think now I see why things were behaving weirdly. I was getting, if I understand this right, multiple executing intentions exactly because I was adding that achievement goal multiple times on the +numdirty event. And apparently invoking the "!cleanroom" goal from within an intention does not create a new separate intention but just adds that to the current intention? Is that a correct understanding?

In either case, this now works exactly as intended with no need for 'atomic' and no weirdness at the end with the final event happening multiple times.

[jomifred]

yes, the !cleanroom creates a sub-goal for the current intention.

your code looks very good for me!

anyway, what about to change the order of plans to clean a bit the context conditions:

@c4 +!cleanroom : numdirty(0) <- .print( "Done" ); !exit.
@c1 +!cleanroom : not visited_upper_left <- .print( "Starting to clean room!" ); goto_upper_left; !cleanroom.
@c2 +!cleanroom : squares_right_available <- .print( "going right"); suck; right; !cleanroom.
@c3 +!cleanroom : rows_down_available  <- .print( "going down and left"); down; full_left; !cleanroom.
@c5 +!cleanroom  <- .print( "I am lost, but keep trying..... waiting for a miracle"); !cleanroom.

(i didn't test... :-))