build.gradle

import edu.wpi.first.gradlerio.GradleRIOPlugin

plugins {
    id "java"
    id "org.jetbrains.kotlin.jvm" version "1.9.21"
    id "edu.wpi.first.GradleRIO" version "2024.3.2"
    id "com.github.gmazzo.buildconfig" version "3.0.0"
}

def ROBOT_MAIN_CLASS = "org.team2471.frc2024.Main"

buildConfig {
    buildConfigField("long", "BUILD_TIME", "${System.currentTimeMillis()}L")
}

// Define my targets (RoboRIO) and artifacts (deployable files)
// This is added by GradleRIO's backing project DeployUtils.
deploy {
    targets {
        roborio(getTargetTypeClass('RoboRIO')) {
            // Team number is loaded either from the .wpilib/wpilib_preferences.json
            // or from command line. If not found an exception will be thrown.
            // You can use getTeamOrDefault(team) instead of getTeamNumber if you
            // want to store a team number in this file.
            team = 2471
            debug = false

            artifacts {
                // First part is artifact name, 2nd is artifact type
                // getTargetTypeClass is a shortcut to get the class type using a string

                frcJava(getArtifactTypeClass('FRCJavaArtifact')) {
                    //targets << "roborio"
                }

                // // Static files artifact
                frcStaticFileDeploy(getArtifactTypeClass('FileTreeArtifact')) {
                    files = project.fileTree('src/main/deploy')
                    directory = '/home/lvuser/deploy'
                }
            }
        }
    }
}

def deployArtifact = deploy.targets.roborio.artifacts.frcJava
var advantageKitVersion = "3.2.0"

repositories {
    mavenCentral()
    maven { setUrl("https://frcmaven.wpi.edu/artifactory/release/")}
    maven { setUrl("https://plugins.gradle.org/m2/")}
    maven { setUrl("https://maven.ctr-electronics.com/release/") }
    maven { setUrl("https://www.revrobotics.com/content/sw/max/sdk/maven/")}
    maven { setUrl("https://maven.photonvision.org/repository/internal")}
//    maven { url 'https://nexus.otake.pw/repository/maven-public/' }
    maven {
        url = uri("https://maven.pkg.github.com/Mechanical-Advantage/AdvantageKit")
        credentials {
            username = "Mechanical-Advantage-Bot"
            password = "\u0067\u0068\u0070\u005f\u006e\u0056\u0051\u006a\u0055\u004f\u004c\u0061\u0079\u0066\u006e\u0078\u006e\u0037\u0051\u0049\u0054\u0042\u0032\u004c\u004a\u006d\u0055\u0070\u0073\u0031\u006d\u0037\u004c\u005a\u0030\u0076\u0062\u0070\u0063\u0051"
        }
    }
}

// Defining my dependencies. In this case, WPILib (+ friends), and vendor libraries.
// Also defines JUnit 4.
dependencies {
    implementation project("meanlib")

    implementation wpi.java.deps.wpilib()
    implementation wpi.java.vendor.java()

    roborioDebug wpi.java.deps.wpilibJniDebug(wpi.platforms.roborio)
    roborioDebug wpi.java.vendor.jniDebug(wpi.platforms.roborio)

    roborioRelease wpi.java.deps.wpilibJniRelease(wpi.platforms.roborio)
    roborioRelease wpi.java.vendor.jniRelease(wpi.platforms.roborio)

    nativeDebug wpi.java.deps.wpilibJniDebug(wpi.platforms.desktop)
    nativeDebug wpi.java.vendor.jniDebug(wpi.platforms.desktop)
    simulationDebug wpi.sim.enableDebug()

    nativeRelease wpi.java.deps.wpilibJniRelease(wpi.platforms.desktop)
    nativeRelease wpi.java.vendor.jniRelease(wpi.platforms.desktop)
    simulationRelease wpi.sim.enableRelease()

    implementation wpi.java.deps.wpilib()
    nativeRelease wpi.java.deps.wpilibJniRelease(wpi.platforms.roborio)
    nativeRelease wpi.java.deps.wpilibJniRelease(wpi.platforms.desktop)

    testImplementation 'junit:junit:4.12'

    compileOnly "org.jetbrains.kotlin:kotlin-gradle-plugin:1.5.31"
    compileOnly 'org.jetbrains.kotlin:kotlin-stdlib:1.5.31'

    // intentionally not using multhreaded coroutines due to potential memory leaks under heavy load
    compileOnly 'org.jetbrains.kotlinx:kotlinx-coroutines-core:1.5.2'
    compileOnly 'com.github.gmazzo.buildconfig:com.github.gmazzo.buildconfig.gradle.plugin:3.0.0'

//    implementation 'pw.otake.pseudoresonance:pixy2-java-api:1.4.1'
    implementation("org.photonvision:photonlib-java:v2024.3.1")
    implementation("org.photonvision:photontargeting-java:v2024.3.1")

    //AdvantageKit libs
    implementation("org.littletonrobotics.akit.junction:junction-core:$advantageKitVersion")
    implementation("org.littletonrobotics.akit.junction:wpilib-shim:$advantageKitVersion")
    implementation("org.littletonrobotics.akit.conduit:conduit-api:$advantageKitVersion")
    implementation("org.littletonrobotics.akit.conduit:conduit-wpilibio:$advantageKitVersion")
}

// Setting up my Jar File. In this case, adding all libraries into the main jar ('fat jar')
// in order to make them all available at runtime. Also adding the manifest so WPILib
// knows where to look for our Robot Class.
jar {
    dependsOn(':meanlib:jar')
    from { configurations.runtimeClasspath.collect { it.isDirectory() ? it : zipTree(it)}}
    manifest GradleRIOPlugin.javaManifest(ROBOT_MAIN_CLASS)

    duplicatesStrategy = DuplicatesStrategy.INCLUDE
}

deployArtifact.jarTask = jar
wpi.java.configureExecutableTasks(jar)

// Simulation configuration (e.g. environment variables).
wpi.sim.addGui().defaultEnabled = true
wpi.sim.addDriverstation()

//Sets the websocket client remote host.
wpi.sim.envVar("HALSIMWS_HOST", "10.0.0.2")
wpi.sim.addWebsocketsServer().defaultEnabled = true

wrapper {
    gradleVersion = '7.6'
    distributionType = Wrapper.DistributionType.BIN
}
//configurations.configureEach {
//    exclude("edu.wpi.first.wpilibj")
//}

tasks.register('checkAkitInstall', JavaExec) {
    dependsOn "classes"
    mainClass = "org.littletonrobotics.junction.CheckInstall"
    classpath = sourceSets.main.runtimeClasspath
}
compileJava.finalizedBy checkAkitInstall

compileKotlin {
    kotlinOptions.jvmTarget = JavaVersion.VERSION_17
    kotlinOptions.freeCompilerArgs += "-opt-in=kotlin.RequiresOptIn"

    sourceCompatibility = JavaVersion.VERSION_17
    targetCompatibility = JavaVersion.VERSION_17
}